Spatial integrals for a pair of 1s basis functions on two sites separated by a distance R

(Subscript[χ, μ])(r)= (((((ζ^3)/π)))^(1/2))(e^(-ζ r))
r is the distance to the atom site where the basis function is centered. 

Formulas are from J. Autschbach, Quantum Theory for Chemical Applications, Oxford University Press, 2021.

Definitions used to test formulas numerically

Clear[χ,r,f,integral1]
χ[r_,ζ_]:=Sqrt[((ζ^3)/π)]Exp[-ζ r]
r1A[1][r_,θ_,R_]:=Sqrt[(((R/2))^2)+(r^2)-2(R/2) r Cos[θ]]
r1A[2][r_,θ_,R_]:=Sqrt[(((R/2))^2)+(r^2)-2(R/2) r Cos[π-θ]]

f[X_][r_,θ_,R_,ζ_]:=χ[r1A[X][r,θ,R],ζ]

integral1[f1_,f2_,R_,ζ1_,ζ2_]:=2Pi NIntegrate[f1[r,θ,R,ζ1]f2[r,θ,R,ζ2](r^2)Sin[θ],{r,0,Infinity},{θ,0,Pi}]

integral1[f[1],f[1],0,1,1]

1-electron integrals

Overlap

Overlap integral: ⟨(Subscript[χ, α])|(Subscript[χ, β])⟩

Same exponent

sOverlap[R_,ζ_]:=With[{w=R ζ},(1+w+((w^2)/3))(E^(-w))]

Different exponents (Autschbach, p.631, which doesn’t include normalization)

sOverlap[0,u_,v_]:=((8 (((u v))^(3/2)))/(((u+v))^3))
sOverlap[R_,u_,u_]:=sOverlap[R,u]
sOverlap[R_,u_,v_]:=With[{d=(u^2)-(v^2)},((8(((u v))^(3/2)))/(R (d^3)))((4u v+R v d)(E^(-u R))-(4 u v-R u d)(E^(-v R)))]

Test numerically

With[{R=1.2,z=.8},{sOverlap[R,z],sOverlap[R,z]-integral1[f[1],f[2],R,z,z]}]
With[{R=0,z1=.8,z2=1.3},{sOverlap[R,z1,z2],sOverlap[R,z1,z2]-integral1[f[1],f[2],R,z1,z2]}]
With[{R=.78,z1=.8,z2=1.3},{sOverlap[R,z1,z2],sOverlap[R,z1,z2]-integral1[f[1],f[2],R,z1,z2]}]

Coulomb

αα Coulomb integral: ⟨(Subscript[χ, α])|(1/r)|(Subscript[χ, α])⟩

coulombαα[0,ζ_]:=ζ
coulombαα[R_,ζ_]:=With[{w=ζ R},(1/R)(1-Exp[-2w](1+w))]

αβ Coulomb integral: ⟨(Subscript[χ, α])|(1/r)|(Subscript[χ, β])⟩

Same exponent

coulombαβ[0,ζ_]:=ζ
coulombαβ[R_,ζ_]:=With[{w=ζ R},(1/R)(w+(w^2))Exp[-w]]

Different exponents

coulombαβ[0,u_,v_]:=((4 (((u v))^(3/2)))/(((u+v))^2))
coulombαβ[R_,u_,v_]:=With[{d=(u^2)-(v^2)},((4(((u v))^(3/2)))/(R (d^2)))(2v (E^(-u R))-(2v-R d)(E^(-v R)))]

αα potential-energy integral: -⟨(Subscript[χ, α])|(1/(Subscript[r, A]))+(1/(Subscript[r, B]))|(Subscript[χ, α])⟩

Vαα[R_,ζ_]:=-ζ-coulombαα[R,ζ]

αβ potential-energy integral: -⟨(Subscript[χ, α])|(1/(Subscript[r, A]))+(1/(Subscript[r, B]))|(Subscript[χ, β])⟩

Vαβ[R_,ζ_]:=-2coulombαβ[R,ζ]

Test numerically

With[{R=1.2,z=.8},{sOverlap[R,z],sOverlap[R,z]-integral1[f[1],f[2],R,z,z]}]
With[{R=0,z1=.8,z2=1.3},{sOverlap[R,z1,z2],sOverlap[R,z1,z2]-integral1[f[1],f[2],R,z1,z2]}]
With[{R=.78,z1=.8,z2=1.3},{sOverlap[R,z1,z2],sOverlap[R,z1,z2]-integral1[f[1],f[2],R,z1,z2]}]

Kinetic energy

αβ kinetic-energy integral: ⟨(Subscript[χ, α])|-(1/2)(∇^2)|(Subscript[χ, β])⟩

Tαβ[R_,ζ_]:=ζ coulombαβ[R,ζ]-((ζ^2)/2)sOverlap[R,ζ]

αα kinetic-energy integral: ⟨(Subscript[χ, α])|-(1/2)(∇^2)|(Subscript[χ, α])⟩

Tαα[R_,ζ_]:=((ζ^2)/2)

αβ kinetic-energy integral: ⟨(Subscript[χ, α])|-(1/2)(∇^2)|(Subscript[χ, β])⟩

Tαβ[R_,ζ_]:=ζ coulombαβ[R,ζ]-((ζ^2)/2)sOverlap[R,ζ]

Hamiltonian

Same exponent

hαα[R_,ζ_]:=Tαα[R,ζ]+Vαα[R,ζ]
hαβ[R_,ζ_]:=Tαβ[R,ζ]+Vαβ[R,ζ]

Different exponents, R = 0 (Levine 5th ed. p432)

hαβ[0,u_,v_]:=-(1/2)(v^2)sOverlap[0,u,v]+((4(v-2)(((u v))^(3/2)))/(((u+v))^2))

2-electron integrals

[αα|αα]

ERIαααα[R_,ζ_]:=(5/8)ζ

[αα|ββ]

ERIααββ[R_,ζ_]:=With[{w=ζ R},(1/R)(1-(E^(-2w))(1+(11/8)w+(3/4)(w^2)+(1/6)(w^3)))]

[αα|αβ]

ERIαααβ[R_,ζ_]:=With[{w=ζ R},(1/R)((E^(-w))((5/16)+(1/8)w+(w^2))-(E^(-3w))((5/16)+(1/8)w))]

[αβ|βα]

ERIαββα[R_,ζ_]:=With[{w=ζ R},(1/R)((E^(-2w))((5/8)w-(23/20)(w^2)-(3/5)(w^3)-(1/15)(w^4))
+(E^(-2w))(EulerGamma+Log[w])((6/5)+(12/5)w+2(w^2)+(4/5)(w^3)+(2/15)(w^4))
+(E^(+2w))ExpIntegralEi[-4w]((6/5)-(12/5)w+2(w^2)-(4/5)(w^3)+(2/15)(w^4))
-ExpIntegralEi[-2w]((12/5)-(4/5)(w^2)+(4/15)(w^4))
)]